summaryrefslogtreecommitdiff
path: root/elm/AdvSearch/Set.elm
blob: 1e3ad18eb8af9fb92e17c9e381723f4188653faa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
module AdvSearch.Set exposing (..)

import Html exposing (..)
import Html.Attributes exposing (..)
import Set
import Lib.Html exposing (..)
import Lib.Util exposing (..)
import Gen.Types as GT
import AdvSearch.Query exposing (..)


type alias Model a =
  { sel    : Set.Set a
  , single : Bool
  , and    : Bool
  , neg    : Bool
  , last   : Set.Set a -- Last selection before switching to single mode, if there were multiple items selected
  }

type Msg a
  = Sel a Bool
  | Neg Bool
  | And Bool
  | Single Bool
  | Mode -- Toggle between single / multi (or) / multi (and)


init : Data -> (Data, Model a)
init dat = (dat, { sel = Set.empty, single = True, and = False, neg = False, last = Set.empty })


update : Msg comparable -> Model comparable -> Model comparable
update msg model =
  let singleMode m =
        { m | sel = if m.single then Set.fromList <| List.take 1 <| Set.toList m.sel
                    else if model.single && not m.single && not (Set.isEmpty model.last) then m.last
                    else m.sel
            , last = if m.single && not model.single && Set.size m.sel > 1 then m.sel else Set.empty }
  in
  case msg of
    Sel v b  -> { model | last = Set.empty, sel = if not b then Set.remove v model.sel else if model.single then Set.fromList [v] else Set.insert v model.sel }
    Neg b    -> { model | neg = b }
    And b    -> { model | and = b }
    Single b -> singleMode { model | single = b }
    Mode     -> singleMode { model | single = not model.single && model.and, and = not model.single && not model.and }


toQuery : (Op -> a -> Query) -> Model a -> Maybe Query
toQuery f m =
  case (m.neg, m.and, Set.toList m.sel) of
    (_,_,[])  -> Nothing
    (n,_,[v]) -> Just (f (if n then Ne else Eq) v)
    (False, False, l) -> Just <| QOr  <| List.map (\v -> f Eq v) l
    (True , False, l) -> Just <| QAnd <| List.map (\v -> f Ne v) l
    (False, True , l) -> Just <| QAnd <| List.map (\v -> f Eq v) l
    (True , True , l) -> Just <| QOr  <| List.map (\v -> f Ne v) l


-- Only recognizes queries generated by setToQuery, doesn't handle alternative query structures.
-- Usage:
--   setFromQuery (\q -> case q of
--                         QStr 2 op v -> Just (op, v)
--                         _ -> Nothing) model
fromQuery : (Query -> Maybe (Op,comparable)) -> Data -> Query -> Maybe (Data, Model comparable)
fromQuery f dat q =
  let single and qs = f qs |> Maybe.andThen (\(op,v) ->
        if op /= Ne && op /= Eq
        then Nothing
        else Just (dat, { sel = Set.fromList [v], and = xor and (op == Ne), neg = (op == Ne), single = True, last = Set.empty }))
      lst mm xqs =
        case (mm, xqs) of
          (Nothing, _) -> Nothing
          (_, [])      -> mm
          (Just (_,m), x :: xs) -> f x |> Maybe.andThen (\(op,v) ->
            if (op /= Ne && op /= Eq) || (op == Ne) /= m.neg
            then Nothing
            else lst (Just (dat, {m | single = False, sel = Set.insert v m.sel})) xs)
  in case q of
      QAnd (x::xs) -> lst (single True  x) xs
      QOr  (x::xs) -> lst (single False x) xs
      _ -> single False q


lblPrefix m = text <| (if m.neg then "¬" else "") ++ (if m.single || Set.size m.sel == 1 then "" else if m.and then "∀ " else "∃ ")


optsMode m canAnd canSingle =
  a [ href "#"
    , onClickD (if canAnd && canSingle then Mode else if canSingle then Single (not m.single) else And (not m.and))
    , title <| if m.single then "Single-selection mode" else if m.and then "Entry must match all selected items" else "Entry must match at least one item"
    ] [ text <| "Mode:" ++ if m.single then "single" else if m.and then "all" else "any" ]

opts m canAnd canSingle = div [ class "opts" ]
  [ optsMode m canAnd canSingle
  , linkRadio m.neg Neg [ text "invert" ]
  ]




-- Language

langView orig model =
  let tprefix = if orig then "O " else "L "
  in
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text <| if orig then "Orig language" else "Language" ]
      [v] -> span [ class "nowrap" ] [ text tprefix, lblPrefix model, langIcon v, text <| Maybe.withDefault "" (lookup v GT.languages) ]
      l   -> span [ class "nowrap" ] <| text tprefix :: lblPrefix model :: List.intersperse (text "") (List.map langIcon l)
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text <| if orig then "Language the visual novel has been originally written in." else "Language(s) in which the visual novel is available." ]
      , opts model (not orig) True
      ]
    , ul [ style "columns" "2"] <| List.map (\(l,t) -> li [] [ linkRadio (Set.member l model.sel) (Sel l) [ langIcon l, text t ] ]) GT.languages
    ]
  )

langFromQuery = fromQuery (\q ->
  case q of
    QStr 2 op v -> Just (op, v)
    _ -> Nothing)

olangFromQuery = fromQuery (\q ->
  case q of
    QStr 3 op v -> Just (op, v)
    _ -> Nothing)




-- Platform

platformView model =
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text "Platform" ]
      [v] -> span [ class "nowrap" ] [ lblPrefix model, platformIcon v, text <| Maybe.withDefault "" (lookup v GT.platforms) ]
      l   -> span [ class "nowrap" ] <| lblPrefix model :: List.intersperse (text "") (List.map langIcon l)
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text "Platforms for which the visual novel is available." ]
      , opts model True True
      ]
    , ul [ style "columns" "2"] <| List.map (\(p,t) ->
        li [classList [("separator", p == "web")]] [ linkRadio (Set.member p model.sel) (Sel p) [ platformIcon p, text t ] ]
      ) GT.platforms
    ]
  )

platformFromQuery = fromQuery (\q ->
  case q of
    QStr 4 op v -> Just (op, v)
    _ -> Nothing)




-- Length

lengthView model =
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text "Length" ]
      [v] -> span [ class "nowrap" ] [ lblPrefix model, text <| Maybe.withDefault "" (lookup v GT.vnLengths) ]
      l   -> span [] [ lblPrefix model, text <| "Length (" ++ String.fromInt (List.length l) ++ ")" ]
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text "Length (estimated play time)" ]
      , opts model False True ]
    , ul [] <| List.map (\(l,t) -> li [] [ linkRadio (Set.member l model.sel) (Sel l) [ text t ] ]) GT.vnLengths
    ]
  )

lengthFromQuery = fromQuery (\q ->
  case q of
    QInt 5 op v -> Just (op, v)
    _ -> Nothing)




-- Character role

roleView model =
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text "Role" ]
      [v] -> span [ class "nowrap" ] [ lblPrefix model, text <| Maybe.withDefault "" (lookup v GT.charRoles) ]
      l   -> span [] [ lblPrefix model, text <| "Role (" ++ String.fromInt (List.length l) ++ ")" ]
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text "Role" ]
      , opts model True True ]
    , ul [] <| List.map (\(l,t) -> li [] [ linkRadio (Set.member l model.sel) (Sel l) [ text t ] ]) GT.charRoles
    ]
  )

roleFromQuery = fromQuery (\q ->
  case q of
    QStr 2 op v -> Just (op, v)
    _ -> Nothing)




-- Blood type

bloodView model =
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text "Blood type" ]
      [v] -> span [ class "nowrap" ] [ lblPrefix model, text <| "Blood type " ++ Maybe.withDefault "" (lookup v GT.bloodTypes) ]
      l   -> span [] [ lblPrefix model, text <| "Blood type (" ++ String.fromInt (List.length l) ++ ")" ]
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text "Blood type" ]
      , opts model False True ]
    , ul [] <| List.map (\(l,t) -> li [] [ linkRadio (Set.member l model.sel) (Sel l) [ text t ] ]) GT.bloodTypes
    ]
  )

bloodFromQuery = fromQuery (\q ->
  case q of
    QStr 3 op v -> Just (op, v)
    _ -> Nothing)




-- Sex / gender

type SexType
  = SexChar   -- chars sex
  | SexSpoil  -- chars sex-spoil
  | SexGender -- staff gender

sexView stype model =
  let lbl = case stype of
              SexChar -> "Sex"
              SexSpoil -> "Spoiler-sex"
              SexGender -> "Gender"
  in
  ( case Set.toList model.sel of
      []  -> b [ class "grayedout" ] [ text lbl ]
      [v] -> span [ class "nowrap" ] [ lblPrefix model, text <| lbl ++ ": " ++ Maybe.withDefault "" (lookup v GT.genders) ]
      l   -> span [] [ lblPrefix model, text <| lbl ++ " (" ++ String.fromInt (List.length l) ++ ")" ]
  , \() ->
    [ div [ class "advheader" ]
      [ h3 [] [ text lbl ]
      , opts model False True ]
    , ul [] <| List.map (\(l,t) -> if stype == SexGender && l == "b" then text "" else li [] [ linkRadio (Set.member l model.sel) (Sel l) [ text t ] ]) GT.genders
    ]
  )

sexFromQuery stype = fromQuery (\q ->
  case (stype, q) of
    (SexChar,  QStr 4 op v) -> Just (op, v)
    (SexSpoil, QStr 5 op v) -> Just (op, v)
    -- TODO: SexGender
    _ -> Nothing)