summaryrefslogtreecommitdiff
path: root/lib/VN3/Types.pm
blob: 15b23010fe80bc14064d69ba98b44ec056ca619e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
# Listings and formatting functions for various data types in the database.

package VN3::Types;

use strict;
use warnings;
use utf8;
use Tie::IxHash;
use TUWF ':Html5';
use POSIX 'strftime', 'ceil';
use Exporter 'import';
use VNDB::Types;

our @EXPORT = qw/
    $UID_RE $VID_RE $RID_RE $SID_RE $CID_RE $PID_RE $IID_RE $DOC_RE
    $VREV_RE $RREV_RE $PREV_RE $SREV_RE $CREV_RE $DREV_RE
    Lang
    Platform
    media_display
    ReleaseDate
    @VN_LENGTHS vn_length_time vn_length_display
    char_roles char_role_display
    vote_display vote_string
    date_display
    vn_relation_reverse vn_relation_display
    producer_relation_reverse producer_relation_display
    spoil_display
    release_types
    minage_display minage_display_full
    resolution_display_full
    gender_display gender_icon
    blood_type_display
/;


# Regular expressions for use in path registration
my $num = qr{[1-9][0-9]{0,6}};
our $UID_RE = qr{u(?<id>$num)};
our $VID_RE = qr{v(?<id>$num)};
our $RID_RE = qr{r(?<id>$num)};
our $SID_RE = qr{s(?<id>$num)};
our $CID_RE = qr{c(?<id>$num)};
our $PID_RE = qr{p(?<id>$num)};
our $IID_RE = qr{i(?<id>$num)};
our $DOC_RE = qr{d(?<id>$num)};
our $VREV_RE = qr{$VID_RE(?:\.(?<rev>$num))?};
our $RREV_RE = qr{$RID_RE(?:\.(?<rev>$num))?};
our $PREV_RE = qr{$PID_RE(?:\.(?<rev>$num))?};
our $SREV_RE = qr{$SID_RE(?:\.(?<rev>$num))?};
our $CREV_RE = qr{$CID_RE(?:\.(?<rev>$num))?};
our $DREV_RE = qr{$DOC_RE(?:\.(?<rev>$num))?};


sub Lang {
    Span class => 'lang-badge', uc $_[0];
}



sub Platform {
    # TODO: Icons
    Img class => 'svg-icon', src => tuwf->conf->{url_static}.'/v3/windows.svg', title => $PLATFORM{$_[0]};
}


sub media_display {
    my($media, $qty) = @_;
    my $med = $MEDIUM{$media};
    return $med->{txt} if !$med->{qty};
    sprintf '%d %s', $qty, $qty == 1 ? $med->{txt} : $med->{plural};
}




sub ReleaseDate {
    my $date = sprintf '%08d', shift||0;
    my $future = $date > strftime '%Y%m%d', gmtime;
    my($y, $m, $d) = ($1, $2, $3) if $date =~ /^([0-9]{4})([0-9]{2})([0-9]{2})$/;

    my $str = $y ==  0 ? 'unknown' : $y == 9999 ? 'TBA' :
              $m == 99 ? sprintf('%04d', $y) :
              $d == 99 ? sprintf('%04d-%02d', $y, $m) :
                         sprintf('%04d-%02d-%02d', $y, $m, $d);

    Txt $str if !$future;
    B class => 'future', $str if $future;
}



our @VN_LENGTHS = (
    # name          time             examples
    [ 'Unknown',    '',              ''                                                  ],
    [ 'Very short', '< 2 hours',     'OMGWTFOTL, Jouka no Monshou, The world to reverse' ],
    [ 'Short',      '2 - 10 hours',  'Narcissu, Saya no Uta, Planetarian'                ],
    [ 'Medium',     '10 - 30 hours', 'Yume Miru Kusuri, Cross†Channel, Crescendo'        ],
    [ 'Long',       '30 - 50 hours', 'Tsukihime, Ever17, Demonbane'                      ],
    [ 'Very long',  '> 50 hours',    'Clannad, Umineko, Fate/Stay Night'                 ],
);

sub vn_length_time {
    my $l = $VN_LENGTHS[$_[0]];
    $l->[1] || $l->[0];
}

sub vn_length_display {
    my $l = $VN_LENGTHS[$_[0]];
    $l->[0].($l->[1] ? " ($l->[1])" : '')
}



sub char_role_display {
    my($role, $num) = @_;
    $CHAR_ROLE{$role}{!$num || $num == 1 ? 'txt' : 'plural'};
}



sub vote_display {
    !$_[0] ? '-' : $_[0] % 10 == 0 ? $_[0]/10 : sprintf '%.1f', $_[0]/10;
}

sub vote_string {
    ['worst ever',
     'awful',
     'bad',
     'weak',
     'so-so',
     'decent',
     'good',
     'very good',
     'excellent',
     'masterpiece']->[ceil(shift()/10)-2];
}



sub date_display {
    strftime '%Y-%m-%d', gmtime $_[0];
}



sub vn_relation_reverse { $VN_RELATION{$_[0]}{reverse} }
sub vn_relation_display { $VN_RELATION{$_[0]}{txt} }



sub producer_relation_reverse { $PRODUCER_RELATION{$_[0]}{reverse} }
sub producer_relation_display { $PRODUCER_RELATION{$_[0]}{txt} }



sub spoil_display {
    ['No spoilers'
    ,'Minor spoilers'
    ,'Spoil me!']->[$_[0]];
}



my @RELEASE_TYPES = qw/complete partial trial/;

sub release_types { @RELEASE_TYPES }


sub minage_display { $AGE_RATING{$_[0]}{txt} }
sub minage_display_full { my $e = $AGE_RATING{$_[0]}; $e->{txt}.($e->{ex} ? " (e.g. $e->{ex})" : '') };



sub resolution_display_full { my $e = $RESOLUTION{$_[0]}; ($e->{cat} ? ucfirst "$e->{cat}: " : '').$e->{txt} }


sub gender_display { $GENDER{$_[0]} }
sub gender_icon { +{qw/m ♂ f ♀ mf ♂♀/}->{$_[0]}||'' }



sub blood_type_display { $BLOOD_TYPE{$_[0]} }


1;