summaryrefslogtreecommitdiff
path: root/lib/VNDB/DB/ULists.pm
blob: a47e848ee83e9a82d1c97b9a53f3afc505417698 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356

package VNDB::DB::ULists;

use strict;
use warnings;
use Exporter 'import';


our @EXPORT = qw|
  dbRListGet dbVNListGet dbVNListList dbVNListAdd dbVNListDel dbRListAdd dbRListDel
  dbVoteGet dbVoteStats dbVoteAdd dbVoteDel
  dbWishListGet dbWishListAdd dbWishListDel
|;


# Options: uid rid
sub dbRListGet {
  my($self, %o) = @_;

  my %where = (
    'uid = ?' => $o{uid},
    $o{rid} ? ('rid IN(!l)' => [ ref $o{rid} ? $o{rid} : [$o{rid}] ]) : (),
  );

  return $self->dbAll(q|
    SELECT uid, rid, status
      FROM rlists
      !W|,
    \%where
  );
}

# Options: uid vid
sub dbVNListGet {
  my($self, %o) = @_;

  my %where = (
    'uid = ?' => $o{uid},
    $o{vid} ? ('vid IN(!l)' => [ ref $o{vid} ? $o{vid} : [$o{vid}] ]) : (),
  );

  return $self->dbAll(q|
    SELECT uid, vid, status
      FROM vnlists
      !W|,
    \%where
  );
}


# Options: uid char voted page results sort reverse
# sort: title vote
sub dbVNListList {
  my($self, %o) = @_;
  $o{results} ||= 50;
  $o{page}    ||= 1;

  my %where = (
    'vl.uid = ?' => $o{uid},
    defined($o{voted}) ? ('vo.vote !s NULL' => $o{voted} ? 'IS NOT' : 'IS') : (),
    defined($o{status})? ('vl.status = ?' => $o{status}) : (),
    $o{char}           ? ('LOWER(SUBSTR(vr.title, 1, 1)) = ?' => $o{char} ) : (),
    defined $o{char} && !$o{char} ? (
      '(ASCII(vr.title) < 97 OR ASCII(vr.title) > 122) AND (ASCII(vr.title) < 65 OR ASCII(vr.title) > 90)' => 1 ) : (),
  );

  my $order = sprintf {
    title => 'vr.title %s',
    vote  => 'vo.vote %s NULLS LAST, vr.title ASC',
  }->{ $o{sort}||'title' }, $o{reverse} ? 'DESC' : 'ASC';

  # execute query
  my($r, $np) = $self->dbPage(\%o, qq|
    SELECT vr.vid, vr.title, vr.original, vl.status, vl.notes, COALESCE(vo.vote, 0) AS vote
      FROM vnlists vl
      JOIN vn v ON v.id = vl.vid
      JOIN vn_rev vr ON vr.id = v.latest
      LEFT JOIN votes vo ON vo.vid = vl.vid AND vo.uid = vl.uid
      !W
      ORDER BY !s|,
    \%where, $order
  );

  # fetch releases and link to VNs
  if(@$r) {
    my %vns = map {
      $_->{rels}=[];
      $_->{vid}, $_->{rels}
    } @$r;

    my $rel = $self->dbAll(q|
      SELECT rv.vid, rr.rid, r.latest, rr.title, rr.original, rr.released, rr.type, rl.status
        FROM rlists rl
        JOIN releases r ON rl.rid = r.id
        JOIN releases_rev rr ON rr.id = r.latest
        JOIN releases_vn rv ON rv.rid = r.latest
        WHERE rl.uid = ?
          AND rv.vid IN(!l)
        ORDER BY rr.released ASC|,
      $o{uid}, [ keys %vns ]
    );

    if(@$rel) {
      my %rel = map {
        $_->{languages}=[];
        $_->{latest}, $_->{languages}
      } @$rel;

      push(@{$rel{$_->{rid}}}, $_->{lang}) for (@{$self->dbAll(q|
        SELECT rid, lang
          FROM releases_lang
          WHERE rid IN(!l)|,
        [ keys %rel ]
      )});
      push @{$vns{$_->{vid}}}, $_ for @$rel;
    }
  }

  return wantarray ? ($r, $np) : $r;
}


# Arguments: uid vid status notes
# vid can be an arrayref only when the rows are already present, in which case an update is done
# status and notes can be undef when an update is done, in which case these fields aren't updated
sub dbVNListAdd {
  my($self, $uid, $vid, $stat, $notes) = @_;
    $self->dbExec(
      'UPDATE vnlists !H WHERE uid = ? AND vid IN(!l)',
      {defined($stat) ? ('status = ?' => $stat ):(),
       defined($notes)? ('notes = ?'  => $notes):()},
      $uid, ref($vid) ? $vid : [ $vid ]
    )
  ||
    $self->dbExec(
      'INSERT INTO vnlists (uid, vid, status, notes) VALUES(?, ?, ?, ?)',
      $uid, $vid, $stat||0, $notes||''
    );
}


# Arguments: uid, vid
sub dbVNListDel {
  my($self, $uid, $vid) = @_;
  $self->dbExec(
    'DELETE FROM vnlists WHERE uid = ? AND vid IN(!l)',
    $uid, ref($vid) ? $vid : [ $vid ]
  );
}


# Arguments: uid rid status
# rid can be an arrayref only when the rows are already present, in which case an update is done
sub dbRListAdd {
  my($self, $uid, $rid, $stat) = @_;
    $self->dbExec(
      'UPDATE rlists SET status = ? WHERE uid = ? AND rid IN(!l)',
      $stat, $uid, ref($rid) ? $rid : [ $rid ]
    )
  ||
    $self->dbExec(
      'INSERT INTO rlists (uid, rid, status) VALUES(?, ?, ?)',
      $uid, $rid, $stat
    );
}


# Arguments: uid, rid
sub dbRListDel {
  my($self, $uid, $rid) = @_;
  $self->dbExec(
    'DELETE FROM rlists WHERE uid = ? AND rid IN(!l)',
    $uid, ref($rid) ? $rid : [ $rid ]
  );
}


# Options: uid vid hide hide_ign results page what sort reverse
# what: user, vn
sub dbVoteGet {
  my($self, %o) = @_;
  $o{results} ||= 50;
  $o{page} ||= 1;
  $o{what} ||= '';
  $o{sort} ||= 'date';
  $o{reverse} //= 1;

  my %where = (
    $o{uid} ? ( 'n.uid = ?' => $o{uid} ) : (),
    $o{vid} ? ( 'n.vid = ?' => $o{vid} ) : (),
    $o{hide} ? ( 'NOT EXISTS(SELECT 1 FROM users_prefs WHERE uid = n.uid AND key = \'hide_list\')' => 1 ) : (),
    $o{hide_ign} ? ( '(NOT u.ign_votes OR u.id = ?)' => $self->authInfo->{id}||0 ) : (),
    $o{vn_char}  ? ( 'LOWER(SUBSTR(vr.title, 1, 1)) = ?' => $o{vn_char} ) : (),
    defined $o{vn_char} && !$o{vn_char} ? (
      '(ASCII(vr.title) < 97 OR ASCII(vr.title) > 122) AND (ASCII(vr.title) < 65 OR ASCII(vr.title) > 90)' => 1 ) : (),
    $o{user_char} ? ( 'LOWER(SUBSTR(u.username, 1, 1)) = ?' => $o{user_char} ) : (),
    defined $o{user_char} && !$o{user_char} ? (
      '(ASCII(u.username) < 97 OR ASCII(u.username) > 122) AND (ASCII(u.username) < 65 OR ASCII(u.username) > 90)' => 1 ) : (),
  );

  my @select = (
    qw|n.vid n.vote n.uid|, q|extract('epoch' from n.date) as date|,
    $o{what} =~ /user/ ? ('u.username') : (),
    $o{what} =~ /vn/ ? (qw|vr.title vr.original|) : (),
  );

  my @join = (
    $o{what} =~ /vn/ ? (
      'JOIN vn v ON v.id = n.vid',
      'JOIN vn_rev vr ON vr.id = v.latest'
    ) : (),
    $o{what} =~ /user/ || $o{hide} ? (
      'JOIN users u ON u.id = n.uid'
    ) : (),
  );

  my $order = sprintf {
    date     => 'n.date %s',
    username => 'u.username %s',
    title    => 'vr.title %s',
    vote     => 'n.vote %s'.($o{what} =~ /vn/ ? ', vr.title ASC' : $o{what} =~ /user/ ? ', u.username ASC' : ''),
  }->{$o{sort}}, $o{reverse} ? 'DESC' : 'ASC';

  my($r, $np) = $self->dbPage(\%o, q|
    SELECT !s
      FROM votes n
      !s
      !W
      ORDER BY !s|,
    join(',', @select), join(' ', @join), \%where, $order
  );

  return wantarray ? ($r, $np) : $r;
}


# Arguments: (uid|vid), id, use_ignore_list
# Returns an arrayref with 10 elements containing the number of votes for index+1
sub dbVoteStats {
  my($self, $col, $id, $ign) = @_;
  my $u = $self->authInfo->{id};
  my $r = [ qw| 0 0 0 0 0 0 0 0 0 0 | ];
  $r->[$_->{vote}-1] = $_->{votes} for (@{$self->dbAll(q|
    SELECT vote, COUNT(vote) as votes
      FROM votes
      !s
      !W
      GROUP BY vote|,
    $ign ? 'JOIN users ON id = uid AND (NOT ign_votes'.($u?sprintf(' OR id = %d',$u):'').')' : '',
    $col ? { '!s = ?' => [ $col, $id ] } : {},
  )});
  return $r;
}


# Adds a new vote or updates an existing one
# Arguments: vid, uid, vote
# vid can be an arrayref only when the rows are already present, in which case an update is done
sub dbVoteAdd {
  my($self, $vid, $uid, $vote) = @_;
  $self->dbExec(q|
    UPDATE votes
      SET vote = ?, date = NOW()
      WHERE vid IN(!l)
      AND uid = ?|,
    $vote, ref($vid) ? $vid : [$vid], $uid
  ) || $self->dbExec(q|
    INSERT INTO votes
      (vid, uid, vote)
      VALUES (!l)|,
    [ $vid, $uid, $vote ]
  );
}


# Arguments: uid, vid
# vid can be an arrayref
sub dbVoteDel {
  my($self, $uid, $vid) = @_;
  $self->dbExec('DELETE FROM votes !W',
    { 'vid IN(!l)' => [ref($vid)?$vid:[$vid]], 'uid = ?' => $uid }
  );
}


# %options->{ uid vid wstat what page results sort reverse }
# what: vn
# sort: title added wstat
sub dbWishListGet {
  my($self, %o) = @_;

  $o{page} ||= 1;
  $o{results} ||= 50;
  $o{what} ||= '';

  my %where = (
    'wl.uid = ?' => $o{uid},
    $o{vid} ? ( 'wl.vid = ?' => $o{vid} ) : (),
    defined $o{wstat} ? ( 'wl.wstat = ?' => $o{wstat} ) : (),
  );

  my $select = q|wl.vid, wl.wstat, extract('epoch' from wl.added) AS added|;
  my @join;
  if($o{what} =~ /vn/) {
    $select .= ', vr.title, vr.original';
    push @join, 'JOIN vn v ON v.id = wl.vid',
    'JOIN vn_rev vr ON vr.id = v.latest';
  }

  my $order = sprintf  {
    title => 'vr.title %s',
    added => 'wl.added %s',
    wstat => 'wl.wstat %2$s, vr.title ASC',
  }->{ $o{sort}||'added' }, $o{reverse} ? 'DESC' : 'ASC', $o{reverse} ? 'ASC' : 'DESC';

  my($r, $np) = $self->dbPage(\%o, q|
    SELECT !s
      FROM wlists wl
      !s
      !W
      ORDER BY !s|,
    $select, join(' ', @join), \%where, $order,
  );

  return wantarray ? ($r, $np) : $r;
}


# Updates or adds a whishlist item
# Arguments: vid, uid, wstat
sub dbWishListAdd {
  my($self, $vid, $uid, $wstat) = @_;
    $self->dbExec(
      'UPDATE wlists SET wstat = ? WHERE uid = ? AND vid IN(!l)',
      $wstat, $uid, ref($vid) eq 'ARRAY' ? $vid : [ $vid ]
    )
  ||
    $self->dbExec(
      'INSERT INTO wlists (uid, vid, wstat) VALUES(!l)',
      [ $uid, $vid, $wstat ]
    );
}


# Arguments: uid, vids
sub dbWishListDel {
  my($self, $uid, $vid) = @_;
  $self->dbExec(
    'DELETE FROM wlists WHERE uid = ? AND vid IN(!l)',
    $uid, ref($vid) eq 'ARRAY' ? $vid : [ $vid ]
  );
}


1;