summaryrefslogtreecommitdiff
path: root/lib/VNWeb/Chars/Edit.pm
blob: 4c19afce6e4f26003f9d131ac77b01497fff3e6b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
package VNWeb::Chars::Edit;

use VNWeb::Prelude;


my $FORM = {
    id         => { required => 0, id => 1 },
    name       => { maxlength => 200 },
    original   => { required => 0, default => '', maxlength => 200 },
    alias      => { required => 0, default => '', maxlength => 500 },
    desc       => { required => 0, default => '', maxlength => 5000 },
    gender     => { default => 'unknown', enum => \%GENDER },
    b_month    => { required => 0, default => 0, uint => 1, range => [ 0, 12 ] },
    b_day      => { required => 0, default => 0, uint => 1, range => [ 0, 31 ] },
    age        => { required => 0, uint => 1, range => [ 0, 32767 ] },
    s_bust     => { required => 0, uint => 1, range => [ 0, 32767 ], default => 0 },
    s_waist    => { required => 0, uint => 1, range => [ 0, 32767 ], default => 0 },
    s_hip      => { required => 0, uint => 1, range => [ 0, 32767 ], default => 0 },
    height     => { required => 0, uint => 1, range => [ 0, 32767 ], default => 0 },
    weight     => { required => 0, uint => 1, range => [ 0, 32767 ] },
    bloodt     => { default => 'unknown', enum => \%BLOOD_TYPE },
    cup_size   => { required => 0, default => '', enum => \%CUP_SIZE },
    hidden     => { anybool => 1 },
    locked     => { anybool => 1 },

    authmod    => { _when => 'out', anybool => 1 },
    editsum    => { _when => 'in out', editsum => 1 },
};

my $FORM_OUT = form_compile out => $FORM;
my $FORM_IN  = form_compile in  => $FORM;
my $FORM_CMP = form_compile cmp => $FORM;


TUWF::get qr{/$RE{crev}/edit} => sub {
    my $e = db_entry c => tuwf->capture('id'), tuwf->capture('rev') or return tuwf->resNotFound;
    return tuwf->resDenied if !can_edit c => $e;

    $e->{authmod} = auth->permDbmod;
    $e->{editsum} = $e->{chrev} == $e->{maxrev} ? '' : "Reverted to revision c$e->{id}.$e->{chrev}";

    framework_ title => "Edit $e->{name}", type => 'c', dbobj => $e, tab => 'edit',
    sub {
        editmsg_ c => $e, "Edit $e->{name}";
        elm_ CharEdit => $FORM_OUT, $e;
    };
};


# XXX: Require VN
TUWF::get qr{/c/new}, sub {
    return tuwf->resDenied if !can_edit c => undef;
    framework_ title => 'Add character',
    sub {
        editmsg_ c => undef, 'Add character';
        elm_ CharEdit => $FORM_OUT, {
            elm_empty($FORM_OUT)->%*,
        };
    };
};


elm_api CharEdit => $FORM_OUT, $FORM_IN, sub {
    my $data = shift;
    my $new = !$data->{id};
    my $e = $new ? { id => 0 } : db_entry c => $data->{id} or return tuwf->resNotFound;
    return elm_Unauth if !can_edit c => $e;

    if(!auth->permDbmod) {
        $data->{hidden} = $e->{hidden}||0;
        $data->{locked} = $e->{locked}||0;
    }
    $data->{desc} = bb_subst_links $data->{desc};
    $data->{b_day} = 0 if !$data->{b_month};

    return elm_Unchanged if !$new && !form_changed $FORM_CMP, $data, $e;
    my($id,undef,$rev) = db_edit c => $e->{id}, $data;
    elm_Redirect "/c$id.$rev";
};

1;