summaryrefslogtreecommitdiff
path: root/lib/VNWeb/Staff/Page.pm
blob: d1ee5bf339ea72f90d7cb197b13090569f6643b2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
package VNWeb::Staff::Page;

use VNWeb::Prelude;
use VNWeb::ULists::Lib;


sub enrich_item {
    my($s) = @_;

    # Add a 'main' flag to each alias
    $_->{main} = $s->{aid} == $_->{aid} for $s->{alias}->@*;

    # Sort aliases by name
    $s->{alias} = [ sort { $a->{name} cmp $b->{name} || ($a->{original}||'') cmp ($b->{original}||'') } $s->{alias}->@* ];
}


sub _rev_ {
    my($s) = @_;
    revision_ $s, \&enrich_item,
        [ alias  => 'Names', fmt => sub {
            txt_ $_->{name};
            txt_ " ($_->{original})" if $_->{original};
            b_ class => 'grayedout', ' (primary)' if $_->{main};
        } ],
        [ gender => 'Gender',     fmt => \%GENDER   ],
        [ lang   => 'Language',   fmt => \%LANGUAGE ],
        [ desc   => 'Description' ],
        revision_extlinks 's'
}


sub _infotable_ {
    my($main, $s) = @_;
    table_ class => 'stripe', sub {
        thead_ sub { tr_ sub {
            td_ colspan => 2, sub {
                b_ style => 'margin-right: 10px', $main->{name};
                b_ class => 'grayedout', style => 'margin-right: 10px', lang => $s->{lang}, $main->{original} if $main->{original};
                abbr_ class => "icons gen $s->{gender}", title => $GENDER{$s->{gender}}, '' if $s->{gender} ne 'unknown';
            }
        } };

        tr_ sub {
            td_ class => 'key', 'Language';
            td_ $LANGUAGE{$s->{lang}};
        };

        my @alias = grep !$_->{main}, $s->{alias}->@*;
        tr_ sub {
            td_ @alias == 1 ? 'Alias' : 'Aliases';
            td_ sub {
                table_ class => 'aliases', sub {
                    tr_ class => 'nostripe', sub {
                        td_ class => 'key', $_->{original} ? () : (colspan => 2), $_->{name};
                        td_ lang => $s->{lang}, $_->{original} if $_->{original};
                    } for @alias;
                };
            };
        } if @alias;

        tr_ sub {
            td_ class => 'key', 'Links';
            td_ sub {
                join_ \&br_, sub { a_ href => $_->[1], $_->[0] }, $s->{extlinks}->@*;
            };
        } if $s->{extlinks}->@*;
    };
}


sub _roles_ {
    my($s) = @_;
    my %alias = map +($_->{aid}, $_), $s->{alias}->@*;

    my $roles = tuwf->dbAlli(q{
        SELECT v.id, vs.aid, vs.role, vs.note, ve.name, ve.official, v.c_released, v.title, v.alttitle
          FROM vn_staff vs
          JOIN vnt v ON v.id = vs.id
          LEFT JOIN vn_editions ve ON ve.id = vs.id AND ve.eid = vs.eid
         WHERE vs.aid IN}, [ keys %alias ], q{
           AND NOT v.hidden
         ORDER BY v.c_released ASC, v.title ASC, ve.lang NULLS FIRST, ve.name NULLS FIRST, vs.role ASC
    });
    return if !@$roles;
    enrich_ulists_widget $roles;

    h1_ class => 'boxtitle', sprintf 'Credits (%d)', scalar @$roles;
    div_ class => 'mainbox browse staffroles', sub {
        table_ class => 'stripe', sub {
            thead_ sub { tr_ sub {
                td_ class => 'tc_ulist', '' if auth;
                td_ class => 'tc1', 'Title';
                td_ class => 'tc2', 'Released';
                td_ class => 'tc3', 'Role';
                td_ class => 'tc4', 'As';
                td_ class => 'tc5', 'Note';
            }};
            my %vns;
            tr_ sub {
                my($v, $a) = ($_, $alias{$_->{aid}});
                td_ class => 'tc_ulist', sub { ulists_widget_ $v if !$vns{$v->{id}}++ } if auth;
                td_ class => 'tc1', sub {
                    a_ href => "/$v->{id}", title => $v->{alttitle}||$v->{title}, shorten $v->{title}, 60;
                    txt_ " $v->{name}" if $v->{name} && $v->{official};
                    b_ class => 'grayedout', " $v->{name}" if $v->{name} && !$v->{official};
                };
                td_ class => 'tc2', sub { rdate_ $v->{c_released} };
                td_ class => 'tc3', $CREDIT_TYPE{$v->{role}};
                td_ class => 'tc4', title => $a->{original}||$a->{name}, $a->{name};
                td_ class => 'tc5', $v->{note};
            } for @$roles;
        };
    };
}


sub _cast_ {
    my($s) = @_;
    my %alias = map +($_->{aid}, $_), $s->{alias}->@*;

    my $cast = tuwf->dbAlli(q{
        SELECT vs.aid, v.id, v.c_released, v.title, v.alttitle, c.id AS cid, c.name AS c_name, c.original AS c_original, vs.note,
               (SELECT MIN(cv.spoil) FROM chars_vns cv WHERE cv.id = c.id AND cv.vid = v.id) AS spoil
          FROM vn_seiyuu vs
          JOIN vnt v ON v.id = vs.id
          JOIN chars c ON c.id = vs.cid
         WHERE vs.aid IN}, [ keys %alias ], q{
           AND NOT v.hidden
           AND NOT c.hidden
         ORDER BY v.c_released ASC, v.title ASC
    });
    return if !@$cast;
    enrich_ulists_widget $cast;

    my $spoilers = viewget->{spoilers};
    my $max_spoil = max(map $_->{spoil}, @$cast);

    div_ class => 'maintabs', sub {
        h1_ sprintf 'Voiced characters (%d)', scalar @$cast;
        ul_ sub {
            li_ mkclass(tabselected => $spoilers == 0), sub { a_ href => '?view='.viewset(spoilers => 0), 'hide spoilers' };
            li_ mkclass(tabselected => $spoilers == 1), sub { a_ href => '?view='.viewset(spoilers => 1), 'minor spoilers' };
            li_ mkclass(tabselected => $spoilers == 2), sub { a_ href => '?view='.viewset(spoilers => 2), 'spoil me!' } if $max_spoil == 2;
        } if $max_spoil;
    };
    div_ class => "mainbox browse staffroles", sub {
        table_ class => 'stripe', sub {
            thead_ sub { tr_ sub {
                td_ class => 'tc_ulist', '' if auth;
                td_ class => 'tc1', sub { txt_ 'Title'; debug_ $cast };
                td_ class => 'tc2', 'Released';
                td_ class => 'tc3', 'Cast';
                td_ class => 'tc4', 'As';
                td_ class => 'tc5', 'Note';
            }};
            my %vns;
            tr_ sub {
                my($v, $a) = ($_, $alias{$_->{aid}});
                td_ class => 'tc_ulist', sub { ulists_widget_ $v if !$vns{$v->{id}}++ } if auth;
                td_ class => 'tc1', sub {
                    a_ href => "/$v->{id}", title => $v->{alttitle}||$v->{title}, shorten $v->{title}, 60;
                };
                td_ class => 'tc2', sub { rdate_ $v->{c_released} };
                td_ class => 'tc3', sub {
                    a_ href => "/$v->{cid}", title => $v->{c_original}||$v->{c_name}, $v->{c_name};
                    spoil_ $_->{spoil};
                };
                td_ class => 'tc4', title => $a->{original}||$a->{name}, $a->{name};
                td_ class => 'tc5', $v->{note};
            } for grep $_->{spoil} <= $spoilers, @$cast;
        };
    };
}


TUWF::get qr{/$RE{srev}} => sub {
    my $s = db_entry tuwf->captures('id', 'rev');
    return tuwf->resNotFound if !$s;

    enrich_item $s;
    enrich_extlinks s => $s;
    my($main) = grep $_->{aid} == $s->{aid}, $s->{alias}->@*;

    framework_ title => $main->{name}, index => !tuwf->capture('rev'), dbobj => $s, hiddenmsg => 1,
        og => {
            description => bb_format $s->{desc}, text => 1
        },
    sub {
        _rev_ $s if tuwf->capture('rev');
        div_ class => 'mainbox staffpage', sub {
            itemmsg_ $s;
            h1_ sub { txt_ $main->{name}; debug_ $s };
            h2_ class => 'alttitle', lang => $s->{lang}, $main->{original} if $main->{original};
            _infotable_ $main, $s;
            div_ class => 'description', sub { lit_ bb_format $s->{desc} };
        };

        _roles_ $s;
        _cast_ $s;
    };
};

1;